Thanks to your help and suggestions I have traced the issue with my display to the following line in my iPXE menu -
console --picture ipxe.png ||Commenting out this line resulted in a working Windows installation - to an iSCSI Target with the Client PC in UEFI Mode with CSM disabled. I tested this by using my original iPXE menu and setup (W530 server with a Client PC connected via a CAT5E Crossover cable), but with this single line in my original iPXE menu commented out.
Whilst I'm so pleased to finally get this working, this is just so bloody frustrating
- I have lost track of the number of tests I have completed and hours wasted. Although it's not all bad as I have learned a lot along the way. Thanks to your inspired/educated guess this is now working 
Successfully installed 64-bit Windows 10.0.14393 (LTSB - 1603) to an iSCSI Target, using StarWind 5.2 iSCSI Target.
If we ever manage an IRL then I owe you a beer.
Misty
P.s. My working iPXE menu -
#!ipxe
#SET BACKGROUND PICTURE AND PROCEED - IF ERROR, GOTO NEXT LINE
#console --picture ipxe.png ||
iseq ${next-server} ${dhcp-server} && goto dhcp ||
set boot-url http://${next-server}
set boot-ip ${next-server}
goto main
:dhcp
set boot-url http://${dhcp-server}
set boot-ip ${dhcp-server}
goto main
#================ Main Menu =================
:main
menu iPXE boot menu
item --gap -- next-server - ${next-server}
item --gap -- dhcp-server - ${dhcp-server}
item --gap -- boot-url - ${boot-url}
item --gap -- boot-ip - ${boot-ip}
item --gap -- ----------------- Options --------------
item iscsia iSCSI - Define IQN and SANHOOK (+wimboot)
item iscsib iSCSI - Define IQN and SANBOOT
item winpe WinPE (wimboot)
item --gap -- ------------------- Misc ---------------
item config View configuration settings
item shell Shell
item exit Exit
choose target && goto ${target}
#============= END Main Menu ================
:iscsia
set gateway 0.0.0.0
set keep-san 1
set initiator-iqn iqn.client
echo -n Enter IQN filename:
read IQN
set iscsi-target iscsi:${boot-ip}::::${IQN}
echo iscsi-target = ${iscsi-target}
prompt Press any key to continue...
sanhook ${iscsi-target}
kernel ${boot-url}/wimboot pause
iseq ${platform} efi && initrd -n bootx64.efi ${boot-url}/bootx64.efi bootx64.efi ||
iseq ${platform} pcbios && initrd -n bootmgr ${boot-url}/bootmgr bootmgr ||
initrd -n BCD ${boot-url}/boot/BCD BCD ||
initrd -n boot.sdi ${boot-url}/boot/boot.sdi boot.sdi ||
initrd -n boot.wim ${boot-url}/boot/boot.wim boot.wim ||
prompt press any key to continue...
boot
:iscsib
set gateway 0.0.0.0
set keep-san 1
set initiator-iqn iqn.client
echo -n Enter IQN filename:
read IQN
set iscsi-target iscsi:${boot-ip}::::${IQN}
echo iscsi-target = ${iscsi-target}
prompt Press any key to continue...
sanboot ${iscsi-target}
boot
:winpe
kernel ${boot-url}/wimboot pause
iseq ${platform} efi && initrd -n bootx64.efi ${boot-url}/bootx64.efi bootx64.efi ||
iseq ${platform} pcbios && initrd -n bootmgr ${boot-url}/bootmgr bootmgr ||
initrd -n BCD ${boot-url}/boot/BCD BCD ||
initrd -n boot.sdi ${boot-url}/boot/boot.sdi boot.sdi ||
initrd -n boot.wim ${boot-url}/boot/boot.wim boot.wim ||
prompt press any key to continue...
boot
:config
config
goto main
:shell
shell
goto main
:exit
exit
).
.
) to run Microsoft iSCSI Software Target 3.3 on Win 8.1.
